Makie

Appearance

spy ​

Makie.spy Function
julia
spy(z::AbstractSparseArray)
spy(x_range::NTuple{2, Number}, y_range::NTuple{2, Number}, z::AbstractSparseArray)
spy(x_range::ClosedInterval, y_range::ClosedInterval, z::AbstractSparseArray)

Visualizes big sparse matrices. Usage:

julia
using SparseArrays, GLMakie
N = 200_000
x = sprand(Float64, N, N, (3(10^6)) / (N*N));
spy(x)
# or if you want to specify the range of x and y:
spy(0..1, 0..1, x)

Plot type

The plot type alias for the spy function is Spy.

source

Examples ​

julia
using CairoMakie
using SparseArrays

N = 10 # dimension of the sparse matrix
p = 0.1 # independent probability that an entry is zero

A = sprand(N, N, p)
f, ax, plt = spy(A, framecolor = :lightgrey, axis=(;
    aspect=1,
    title = "Visualization of a random sparse matrix")
)

hidedecorations!(ax) # remove axis labeling

f

Orientation ​

spy, like heatmap and image, treats the first index of the given matrix as the x dimension and the second as the y dimension. This is different from when a matrix is printed, where the first index expands downwards and the second to the right. rotr90 can be used to match the Makie plot with the way Julia prints the matrix.

julia
using CairoMakie
using SparseArrays

S = spzeros(4, 4)
S[:, 1] .= 2.0
S[1, 2:4] .= 1.0
#=
Prints as:
4×4 SparseMatrixCSC{Float64, Int64} with 7 stored entries:
 2.0  1.0  1.0  1.0
 2.0   ⋅    ⋅    ⋅
 2.0   ⋅    ⋅    ⋅
 2.0   ⋅    ⋅    ⋅
=#

M = Matrix(S)

f = Figure(size = (600, 500))

a, p = heatmap(
    f[1, 1], M,
    colorrange = (1, 2), lowclip = :transparent,
    colormap = Categorical(:viridis), # just for Colorbar
    axis = (title = "heatmap",)
)
Colorbar(f[1:2, 3], p)
a, p = spy(f[1, 2], S, axis = (title = "spy",))

a, p = heatmap(
    f[2, 1], rotr90(M),
    colorrange = (1, 2), lowclip = :transparent,
    axis = (title = "rotated heatmap",)
)
a, p = spy(f[2, 2], rotr90(S), axis = (title = "rotated spy",))

f

Attributes ​

alpha ​

Defaults to 1.0

The alpha value of the colormap or color attribute. Multiple alphas like in plot(alpha=0.2, color=(:red, 0.5)), will get multiplied.

clip_planes ​

Defaults to @inherit clip_planes automatic

Clip planes offer a way to do clipping in 3D space. You can set a Vector of up to 8 Plane3f planes here, behind which plots will be clipped (i.e. become invisible). By default clip planes are inherited from the parent plot or scene. You can remove parent clip_planes by passing Plane3f[].

color ​

Defaults to nothing

Per default the color of the markers will be determined by the value in the matrix, but can be overwritten via color.

colormap ​

Defaults to @inherit colormap :viridis

Sets the colormap that is sampled for numeric colors. PlotUtils.cgrad(...), Makie.Reverse(any_colormap) can be used as well, or any symbol from ColorBrewer or PlotUtils. To see all available color gradients, you can call Makie.available_gradients().

colorrange ​

Defaults to automatic

The values representing the start and end points of colormap.

colorscale ​

Defaults to identity

The color transform function. Can be any function, but only works well together with Colorbar for identity, log, log2, log10, sqrt, logit, Makie.pseudolog10, Makie.Symlog10, Makie.AsinhScale, Makie.SinhScale, Makie.LogScale, Makie.LuptonAsinhScale, and Makie.PowerScale.

depth_shift ​

Defaults to 0.0

Adjusts the depth value of a plot after all other transformations, i.e. in clip space, where -1 <= depth <= 1. This only applies to GLMakie and WGLMakie and can be used to adjust render order (like a tunable overdraw).

framecolor ​

Defaults to :black

By default a frame will be drawn around the data, which uses the framecolor attribute for its color.

framesize ​

Defaults to 1

The linewidth of the frame

framevisible ​

Defaults to true

Whether or not to draw the frame.

fxaa ​

Defaults to true

Adjusts whether the plot is rendered with fxaa (fast approximate anti-aliasing, GLMakie only). Note that some plots implement a better native anti-aliasing solution (scatter, text, lines). For them fxaa = true generally lowers quality. Plots that show smoothly interpolated data (e.g. image, surface) may also degrade in quality as fxaa = true can cause blurring.

highclip ​

Defaults to automatic

The color for any value above the colorrange.

inspectable ​

Defaults to @inherit inspectable

Sets whether this plot should be seen by DataInspector. The default depends on the theme of the parent scene.

inspector_clear ​

Defaults to automatic

Sets a callback function (inspector, plot) -> ... for cleaning up custom indicators in DataInspector.

inspector_hover ​

Defaults to automatic

Sets a callback function (inspector, plot, index) -> ... which replaces the default show_data methods.

inspector_label ​

Defaults to automatic

Sets a callback function (plot, index, position) -> string which replaces the default label generated by DataInspector.

lowclip ​

Defaults to automatic

The color for any value below the colorrange.

marker ​

Defaults to Rect

Can be any of the markers supported by scatter!. Note, for huge sparse arrays, one should use FastPixel, which is a very fast, but can only render square markers. So, without Axis(...; aspect=1), the markers won't have the correct size. Compare:

julia
data = sprand(10, 10, 0.5)
f = Figure()
spy(f[1, 1], data; marker=FastPixel())
spy(f[1, 2], data; marker=FastPixel(), axis=(; aspect=1))
f

marker_gap ​

Defaults to 0

Makes the marker size smaller to create a gap between the markers. The unit of this is in data space.

markersize ​

Defaults to automatic

markersize=automatic, will make the marker size fit the data - but can also be set manually.

model ​

Defaults to automatic

Sets a model matrix for the plot. This overrides adjustments made with translate!, rotate! and scale!.

nan_color ​

Defaults to :transparent

The color for NaN values.

overdraw ​

Defaults to false

Controls if the plot will draw over other plots. This specifically means ignoring depth checks in GL backends

rasterize ​

Defaults to @inherit rasterize false

Controls whether CairoMakie rasterizes a plot (true, >0) or not (false, 0). If an integer is given, it sets the pixel density for rasterization.

space ​

Defaults to :data

Sets the transformation space for box encompassing the plot. See Makie.spaces() for possible inputs.

ssao ​

Defaults to false

Adjusts whether the plot is rendered with ssao (screen space ambient occlusion). Note that this only makes sense in 3D plots and is only applicable with fxaa = true.

transformation ​

Defaults to :automatic

Controls the inheritance or directly sets the transformations of a plot. Transformations include the transform function and model matrix as generated by translate!(...), scale!(...) and rotate!(...). They can be set directly by passing a Transformation() object or inherited from the parent plot or scene. Inheritance options include:

  • :automatic: Inherit transformations if the parent and child space is compatible

  • :inherit: Inherit transformations

  • :inherit_model: Inherit only model transformations

  • :inherit_transform_func: Inherit only the transform function

  • :nothing: Inherit neither, fully disconnecting the child's transformations from the parent

Another option is to pass arguments to the transform!() function which then get applied to the plot. For example transformation = (:xz, 1.0) which rotates the xy plane to the xz plane and translates by 1.0. For this inheritance defaults to :automatic but can also be set through e.g. (:nothing, (:xz, 1.0)).

transparency ​

Defaults to false

Adjusts how the plot deals with transparency. In GLMakie transparency = true results in using Order Independent Transparency.

visible ​

Defaults to true

Controls whether the plot gets rendered or not.