barplot

Makie.barplot Function

barplot(positions, heights; kwargs...)

Plots bars of the given heights at the given (scalar) positions.

Plot type

The plot type alias for the barplot function is BarPlot.

source

Examples

using CairoMakie
f = Figure()
Axis(f[1, 1])

xs = 1:0.2:10
ys = 0.5 .* sin.(xs)

barplot!(xs, ys, color = :red, strokecolor = :black, strokewidth = 1)
barplot!(xs, ys .- 1, fillto = -1, color = xs, strokecolor = :black, strokewidth = 1)

f

using CairoMakie
xs = 1:0.2:10
ys = 0.5 .* sin.(xs)

barplot(xs, ys, gap = 0, color = :gray85, strokecolor = :black, strokewidth = 1)

Grouping

The first argument of barplot can double as a category or group identifier. All height values passed through the second that have the same category value will be combined into one bar.

using CairoMakie
tbl = (cat = [1, 1, 1, 2, 2, 2, 3, 3, 3],
       height = 0.1:0.1:0.9,
       grp = [1, 2, 3, 1, 2, 3, 1, 2, 3],
       grp1 = [1, 2, 2, 1, 1, 2, 1, 1, 2],
       grp2 = [1, 1, 2, 1, 2, 1, 1, 2, 1]
       )

barplot(tbl.cat, tbl.height, color = tbl.grp,
        axis = (xticks = (1:3, ["left", "middle", "right"]),
                title = "Stacked bars"),
        )

Within a category, values can be further separated into sub groups using stack and/or dodge. In the tbl above, grp marks the values in each category as the first, second and third value of the respective category. Passing this to stack will separate the category bars into 3 smaller stacking bars. Each of them represents one height value, with group 1 at the bottom and 3 at the top.

barplot(tbl.cat, tbl.height,
        stack = tbl.grp,
        color = tbl.grp,
        axis = (xticks = (1:3, ["left", "middle", "right"]),
                title = "Stacked bars"),
        )

Passing grp to dodge will instead draw the individual height values as separate bars side by side. Here 1 is the left most and 3 the right most bar. The gap between dodged bars can be adjusted with dodge_gap.

barplot(tbl.cat, tbl.height,
        dodge = tbl.grp,
        color = tbl.grp,
        axis = (xticks = (1:3, ["left", "middle", "right"]),
                title = "Dodged bars"),
        )

Note that dodge will create slots based on the maximum group value. If we replaced 3 with 4 in grp a gap would be drawn between bars of group 2 and group 4.

barplot(tbl.cat, tbl.height,
        dodge = [1, 2, 4, 1, 2, 4, 1, 2, 4],
        color = [1, 2, 4, 1, 2, 4, 1, 2, 4],
        axis = (xticks = (1:3, ["left", "middle", "right"]),
                title = "Dodged bars"),
        )

Dodging and stacking can also be combined. Multiple values that belong to the same dodge group can be further separated using a different stack group:

barplot(tbl.cat, tbl.height,
        dodge = tbl.grp1,
        stack = tbl.grp2,
        color = tbl.grp,
        axis = (xticks = (1:3, ["left", "middle", "right"]),
                title = "Dodged and stacked bars"),
        )

colors = Makie.wong_colors()

# Figure and Axis
fig = Figure()
ax = Axis(fig[1,1], xticks = (1:3, ["left", "middle", "right"]),
        title = "Dodged bars with legend")

# Plot
barplot!(ax, tbl.cat, tbl.height,
        dodge = tbl.grp,
        color = colors[tbl.grp])

# Legend
labels = ["group 1", "group 2", "group 3"]
elements = [PolyElement(polycolor = colors[i]) for i in 1:length(labels)]
title = "Groups"

Legend(fig[1,2], elements, labels, title)

fig

barplot(
    tbl.cat, tbl.height,
    dodge = tbl.grp,
    color = tbl.grp,
    bar_labels = :y,
    axis = (xticks = (1:3, ["left", "middle", "right"]),
            title = "Dodged bars horizontal with labels"),
    colormap = [:red, :green, :blue],
    color_over_background=:red,
    color_over_bar=:white,
    flip_labels_at=0.85,
    direction=:x,
)

using CairoMakie
barplot([-1, -0.5, 0.5, 1],
    bar_labels = :y,
    axis = (title="Fonts + flip_labels_at",),
    label_size = 20,
    flip_labels_at=(-0.8, 0.8),
    label_color=[:white, :green, :black, :white],
    label_formatter = x-> "Flip at $(x)?",
    label_offset = 10
)

using CairoMakie
gantt = (
    machine = [1, 2, 1, 2],
    job = [1, 1, 2, 3],
    task = [1, 2, 3, 3],
    start = [1, 3, 3.5, 5],
    stop = [3, 4, 5, 6]
)

fig = Figure()
ax = Axis(
    fig[2,1],
    yticks = (1:2, ["A","B"]),
    ylabel = "Machine",
    xlabel = "Time"
)
xlims!(ax, 0, maximum(gantt.stop))

cmap = Makie.to_colormap(:tab10)

barplot!(
    gantt.machine,
    gantt.stop,
    fillto = gantt.start,
    direction = :x,
    color = gantt.job,
    colormap = cmap,
    colorrange = (1, length(cmap)),
    gap = 0.5,
    bar_labels = ["task #$i" for i in gantt.task],
    label_position = :center,
    label_color = :white,
    label = ["job #$i" => (; color = i) for i in unique(gantt.job)]
)

Legend(fig[1,1], ax, "Jobs", orientation=:horizontal, tellwidth = false, tellheight = true)

fig

Attributes

alpha

Defaults to 1.0

The alpha value of the colormap or color attribute. Multiple alphas like in plot(alpha=0.2, color=(:red, 0.5)), will get multiplied.

bar_labels

Defaults to nothing

Labels added at the end of each bar.

clip_planes

Defaults to @inherit clip_planes automatic

Clip planes offer a way to do clipping in 3D space. You can set a Vector of up to 8 Plane3f planes here, behind which plots will be clipped (i.e. become invisible). By default clip planes are inherited from the parent plot or scene. You can remove parent clip_planes by passing Plane3f[].

color

Defaults to @inherit patchcolor

Sets the color of bars.

color_over_background

Defaults to automatic

Sets the color of labels that are drawn outside of bars. Defaults to label_color

color_over_bar

Defaults to automatic

Sets the color of labels that are drawn inside of/over bars. Defaults to label_color

colormap

Defaults to @inherit colormap :viridis

Sets the colormap that is sampled for numeric colors. PlotUtils.cgrad(...), Makie.Reverse(any_colormap) can be used as well, or any symbol from ColorBrewer or PlotUtils. To see all available color gradients, you can call Makie.available_gradients().

colorrange

Defaults to automatic

The values representing the start and end points of colormap.

colorscale

Defaults to identity

The color transform function. Can be any function, but only works well together with Colorbar for identity, log, log2, log10, sqrt, logit, Makie.pseudolog10, Makie.Symlog10, Makie.AsinhScale, Makie.SinhScale, Makie.LogScale, Makie.LuptonAsinhScale, and Makie.PowerScale.

cycle

Defaults to [:color => :patchcolor]

Sets which attributes to cycle when creating multiple plots. The values to cycle through are defined by the parent Theme. Multiple cycled attributes can be set by passing a vector. Elements can

• directly refer to a cycled attribute, e.g. :color

• map a cycled attribute to a palette attribute, e.g. :linecolor => :color

• map multiple cycled attributes to a palette attribute, e.g. [:linecolor, :markercolor] => :color

depth_shift

Defaults to 0.0

Adjusts the depth value of a plot after all other transformations, i.e. in clip space, where -1 <= depth <= 1. This only applies to GLMakie and WGLMakie and can be used to adjust render order (like a tunable overdraw).

direction

Defaults to :y

Controls the direction of the bars. can be :y (height is vertical) or :x (height is horizontal).

dodge

Defaults to automatic

Dodge can be used to separate bars drawn at the same position. For this each bar is given an integer value corresponding to its position relative to the given positions. E.g. with positions = [1, 1, 1, 2, 2, 2] we have 3 bars at each position which can be separated by dodge = [1, 2, 3, 1, 2, 3].

dodge_gap

Defaults to 0.03

Sets the gap between dodged bars relative to the size of the dodged bars.

fillto

Defaults to automatic

Controls the baseline of the bars. This is zero in the default automatic case unless the barplot is in a log-scaled Axis. With a log scale, the automatic default is half the minimum value because zero is an invalid value for a log scale.

flip_labels_at

Defaults to Inf

Sets a height value beyond which labels are drawn inside the bar instead of outside.

fxaa

Defaults to true

Adjusts whether the plot is rendered with fxaa (fast approximate anti-aliasing, GLMakie only). Note that some plots implement a better native anti-aliasing solution (scatter, text, lines). For them fxaa = true generally lowers quality. Plots that show smoothly interpolated data (e.g. image, surface) may also degrade in quality as fxaa = true can cause blurring.

gap

Defaults to 0.2

The final width of the bars is calculated as w * (1 - gap) where w is the width of each bar as determined with the width attribute. When dodge is used the w corresponds to the width of undodged bars, making this control the gap between groups.

highclip

Defaults to automatic

The color for any value above the colorrange.

inspectable

Defaults to @inherit inspectable

Sets whether this plot should be seen by DataInspector. The default depends on the theme of the parent scene.

inspector_clear

Defaults to automatic

Sets a callback function (inspector, plot) -> ... for cleaning up custom indicators in DataInspector.

inspector_hover

Defaults to automatic

Sets a callback function (inspector, plot, index) -> ... which replaces the default show_data methods.

inspector_label

Defaults to automatic

Sets a callback function (plot, index, position) -> string which replaces the default label generated by DataInspector.

label_align

Defaults to automatic

Sets the text alignment of labels.

label_color

Defaults to @inherit textcolor

Sets the color of labels.

label_font

Defaults to @inherit font

The font of the bar labels.

label_formatter

Defaults to bar_label_formatter

Formatting function which is applied to bar labels before they are passed on text()

label_offset

Defaults to 5

The distance of the labels from the bar ends in screen units. Does not apply when label_position = :center.

label_position

Defaults to :end

The position of each bar's label relative to the bar. Possible values are :end or :center.

label_rotation

Defaults to 0π

Sets the text rotation of labels in radians.

label_size

Defaults to @inherit fontsize

The font size of the bar labels.

lowclip

Defaults to automatic

The color for any value below the colorrange.

model

Defaults to automatic

Sets a model matrix for the plot. This overrides adjustments made with translate!, rotate! and scale!.

n_dodge

Defaults to automatic

Sets the maximum integer for dodge. This sets how many bars can be placed at a given position, controlling their width.

nan_color

Defaults to :transparent

The color for NaN values.

offset

Defaults to 0.0

Offsets all bars by the given real value. Can also be set per-bar.

overdraw

Defaults to false

Controls if the plot will draw over other plots. This specifically means ignoring depth checks in GL backends

rasterize

Defaults to @inherit rasterize false

Controls whether CairoMakie rasterizes a plot (true, >0) or not (false, 0). If an integer is given, it sets the pixel density for rasterization.

space

Defaults to :data

Sets the transformation space for box encompassing the plot. See Makie.spaces() for possible inputs.

ssao

Defaults to false

Adjusts whether the plot is rendered with ssao (screen space ambient occlusion). Note that this only makes sense in 3D plots and is only applicable with fxaa = true.

stack

Defaults to automatic

Similar to dodge, this allows bars at the same positions to be stacked by identifying their stack position with integers. E.g. with positions = [1, 1, 1, 2, 2, 2] each group of 3 bars can be stacked with stack = [1, 2, 3, 1, 2, 3].

strokecolor

Defaults to @inherit patchstrokecolor

Sets the outline color of bars.

strokewidth

Defaults to @inherit patchstrokewidth

Sets the outline linewidth of bars.

transformation

Defaults to :automatic

Controls the inheritance or directly sets the transformations of a plot. Transformations include the transform function and model matrix as generated by translate!(...), scale!(...) and rotate!(...). They can be set directly by passing a Transformation() object or inherited from the parent plot or scene. Inheritance options include:

• :automatic: Inherit transformations if the parent and child space is compatible

• :inherit: Inherit transformations

• :inherit_model: Inherit only model transformations

• :inherit_transform_func: Inherit only the transform function

• :nothing: Inherit neither, fully disconnecting the child's transformations from the parent

Another option is to pass arguments to the transform!() function which then get applied to the plot. For example transformation = (:xz, 1.0) which rotates the xy plane to the xz plane and translates by 1.0. For this inheritance defaults to :automatic but can also be set through e.g. (:nothing, (:xz, 1.0)).

transparency

Defaults to false

Adjusts how the plot deals with transparency. In GLMakie transparency = true results in using Order Independent Transparency.

visible

Defaults to true

Controls whether the plot gets rendered or not.

width

Defaults to automatic

The gapless width of the bars. If automatic, the width w is calculated as minimum(diff(sort(unique(positions))). The actual width of the bars is calculated as w * (1 - gap).