surface

surface(x, y, z)

Plots a surface, where (x, y) define a grid whose heights are the entries in z . x and y may be Vectors which define a regular grid, or Matrices which define an irregular grid.

Surface has the conversion trait ContinuousSurface <: SurfaceLike .

Attributes

Specific to `Surface`

lowclip::Union{Nothing, Symbol, <:Colorant} = nothing sets a color for any value below the colorrange.
highclip::Union{Nothing, Symbol, <:Colorant} = nothing sets a color for any value above the colorrange.
invert_normals::Bool = false inverts the normals generated for the surface. This can be useful to illuminate the other side of the surface.

Generic

visible::Bool = true sets whether the plot will be rendered or not.
overdraw::Bool = false sets whether the plot will draw over other plots. This specifically means ignoring depth checks in GL backends.
transparency::Bool = false adjusts how the plot deals with transparency. In GLMakie transparency = true results in using Order Independent Transparency.
fxaa::Bool = true adjusts whether the plot is rendered with fxaa (anti-aliasing).
inspectable::Bool = true sets whether this plot should be seen by DataInspector .
depth_shift::Float32 = 0f0 adjusts the depth value of a plot after all other transformations, i.e. in clip space, where 0 <= depth <= 1 . This only applies to GLMakie and WGLMakie and can be used to adjust render order (like a tunable overdraw).
model::Makie.Mat4f sets a model matrix for the plot. This replaces adjustments made with translate! , rotate! and scale! .
colormap::Union{Symbol, Vector{<:Colorant}} = :viridis sets the colormap that is sampled for numeric color s.
colorrange::Tuple{<:Real, <:Real} sets the values representing the start and end points of colormap .
nan_color::Union{Symbol, <:Colorant} = RGBAf(0,0,0,0) sets a replacement color for color = NaN .
space::Symbol = :data sets the transformation space for vertices generated by surface. See Makie.spaces() for possible inputs.

Generic 3D

shading = true enables lighting.
diffuse::Vec3f = Vec3f(0.4) sets how strongly the red, green and blue channel react to diffuse (scattered) light.
specular::Vec3f = Vec3f(0.2) sets how strongly the object reflects light in the red, green and blue channels.
shininess::Real = 32.0 sets how sharp the reflection is.
ssao::Bool = false adjusts whether the plot is rendered with ssao (screen space ambient occlusion). Note that this only makes sense in 3D plots and is only applicable with fxaa = true .

Examples

using GLMakie

xs = LinRange(0, 10, 100)
ys = LinRange(0, 15, 100)
zs = [cos(x) * sin(y) for x in xs, y in ys]

surface(xs, ys, zs, axis=(type=Axis3,))

using GLMakie
using DelimitedFiles

volcano = readdlm(Makie.assetpath("volcano.csv"), ',', Float64)

surface(volcano,
    colormap = :darkterrain,
    colorrange = (80, 190),
    axis=(type=Axis3, azimuth = pi/4))

using SparseArrays
using LinearAlgebra
using GLMakie

# This example was provided by Moritz Schauer (@mschauer).

#=
Define the precision matrix (inverse covariance matrix)
for the Gaussian noise matrix.  It approximately coincides
with the Laplacian of the 2d grid or the graph representing
the neighborhood relation of pixels in the picture,
https://en.wikipedia.org/wiki/Laplacian_matrix
=#
function gridlaplacian(m, n)
    S = sparse(0.0I, n*m, n*m)
    linear = LinearIndices((1:m, 1:n))
    for i in 1:m
        for j in 1:n
            for (i2, j2) in ((i + 1, j), (i, j + 1))
                if i2 <= m && j2 <= n
                    S[linear[i, j], linear[i2, j2]] -= 1
                    S[linear[i2, j2], linear[i, j]] -= 1
                    S[linear[i, j], linear[i, j]] += 1
                    S[linear[i2, j2], linear[i2, j2]] += 1
                end
            end
        end
    end
    return S
end

# d is used to denote the size of the data
d = 150

 # Sample centered Gaussian noise with the right correlation by the method
 # based on the Cholesky decomposition of the precision matrix
data = 0.1randn(d,d) + reshape(
        cholesky(gridlaplacian(d,d) + 0.003I) \ randn(d*d),
        d, d
)

surface(data; shading=false, colormap = :deep)
surface(data; shading=false, colormap = :deep)

These docs were autogenerated using Makie: v0.17.13, GLMakie: v0.6.13, CairoMakie: v0.8.13, WGLMakie: v0.6.13